Did you know ... Search Documentation:
Predicate append/2
Availability::- use_module(library(lists)).(can be autoloaded)
Sourceappend(+ListOfLists, ?List)
Concatenate a list of lists. Is true if ListOfLists is a list of lists, and List is the concatenation of these lists.
ListOfLists must be a list of possibly partial lists

Examples

?- append([[1,2], [3]], List).
List = [1,2,3].
Use append/3 for substitution in a list

Use append/3 for substitution in a list

The append/3 predicate can be used to split and join lists. We can combine that to realise substituting all appearances of a sublist into another as illustrated below.

  • append(This, After, Rest) creates a pattern from This, i.e., the list Rest starts with This.
  • append(Before, Rest, MyStr) matches the pattern against the input list. On a match we commit (!). Now Before is the input list before the match and After is the input list after the match.
  • Recursively replace in After
  • Join the parts.
subst(This, That, MyStr, Result) :-
    append(This, After, Rest),
    append(Before, Rest, MyStr),
    !,
    subst(This, That, After, AfterResult),
    append([Before,That,AfterResult], Result).
subst(_, _, S, S).
?- portray_text(true).
true.

?- subst(`this`,`that`,`athishellothis`,R).
R = `athathellothat`.
Tags are associated to your profile if you are logged in
Tags:
LogicalCaptain said (2020-04-08T15:33:22):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Bletch

This must be one of the worst-named predicates in the entire galaxy.

concatenate_lists/2 ... no? no. Must be named append/2 otherwise it's not codegolfy enough.

Tricks

How to remove an element from a list (which must contain it) using append/2 once, but at each possible position in turn. Best used with once/1

remove(Lin,Elem,Lout) :-
   append([Front,[Elem],Back],Lin),  % decompose
   append([Front,Back],Lout).        % recompose

Examples:

?- remove([a,b,c,d,xxx,f],xxx,Lout).
Lout = [a, b, c, d, f] ;
false.

?- remove([a,xxx,c,d,xxx,f],xxx,Lout).
Lout = [a, c, d, xxx, f] ;
Lout = [a, xxx, c, d, f] ;
false.

?- remove([a,b,c,d,e,f],xxx,Lout).
false.

?- remove([a,b,c,d,e,f],A,Lout).
A = a,
Lout = [b, c, d, e, f] ;
A = b,
Lout = [a, c, d, e, f] ;
A = c,
Lout = [a, b, d, e, f] ;
A = d,
Lout = [a, b, c, e, f] ;
A = e,
Lout = [a, b, c, d, f] ;
A = f,
Lout = [a, b, c, d, e] ;
false.