Did you know ... Search Documentation:
Predicate atomics_to_string/2
Availability:built-in
atomics_to_string(+List, -String)
List is a list of strings, atoms, or number types. Succeeds if String can be unified with the concatenated elements of List. Equivalent to atomics_to_string(List,’’, String).

Examples

Convert a string of 0s and 1s to an integer

Convert a string of 0s and 1s to an integer

This shows how to convert almost any "string" of 0s and 1s to an integer.

It takes advantage of the built-in term reading, thus avoiding an explicit loop and arithmetic.

binary_string_to_int(Str, Int) :-
    (   ( string(Str) ; atom(Str) )
    ->  atomics_to_string(["0b", Str], Literal)
    ;   is_list(Str)
    ->  atomics_to_string(["0b"|Str], Literal)
    ;   type_error(string_type, Str)
    ),
    catch(term_string(Int, Literal, []),
          error(syntax_error(_), _),
          type_error(string_of_0s_and_1s, Str)).
?- binary_string_to_int('101', X).
X = 5.

?- binary_string_to_int([0, 0, 1, 0, 1], X).
X = 5.

?- binary_string_to_int(["1", "1", "0"], X).
X = 6.
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • concatenation_of_strings
  • string_list_concat
LogicalCaptain said (2021-05-08T16:44:39):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Your choices

Your choice of predicate is as follows:

Two concatenable terms as input (can split)

Two more general concatenable terms as input (cannot split because arguments 1 and 2 are too general)

A list of concatenable terms as input (never split)

  • atomic_list_concat/2 - generates atom at argument 2. Refuses string at argument 2 in accept mode (that's likely a bug).
  • atomics_to_string/2 - generates string at argument 2. Refuses atom at argument 2 in accept mode (that's likely a bug).

A list of concatenable terms as input, and intersperse another string (can split at interspersed string)

  • atomic_list_concat/3 - concatenate with separator ("intersperse", "join"). Refuses string at argument 3 in accept mode (that's likely a bug).
  • atomics_to_string/3 - concatenate with separator ("intersperse", "join"). Refuses atom at argument 3 in accept mode (that's likely a bug).

Examples

?- atomics_to_string([],S).
S = "".
?- atomics_to_string([a,b,c],S).
S = "abc".
?- atomics_to_string([a,1,c],S).
S = "a1c".

Integers stay integers and aren't mapped to chars:

?- atomics_to_string([a,"b",122,0'f,d],X).
X = "ab122102d".

Verifying:

?- atomics_to_string([a,b,c],"abc").
true.

atomics_to_string/2 insists on seeing a string at argument 2 place:

?- atomics_to_string([a,b,c],'abc').
false.

It doesn't break a string apart:

?- atomics_to_string(X,"abc").
ERROR: Arguments are not sufficiently instantiated

No flattening:

?- atomics_to_string([a,[b,c],d],"abc").
ERROR: Type error: `text' expected, found `[b,c]' (a list)